function TKMDeliverQueue.CalculateBid(iO,iD:Integer; aSerf: TKMUnitSerf):Single;
begin
   //Basic Bid is length of route
   if fDemand[iD].Loc_House <> nil then
   begin
     Result := KMLength(fOffer[iO].Loc_House.GetEntrance, fDemand[iD].Loc_House.GetEntrance)
     //Resource ratios are also considered
     + fPlayers[fOffer[iO].Loc_House.Owner].Stats.Ratio[fDemand[iD].Ware, fDemand[iD].Loc_House.HouseType];
   end
   else
     Result := KMLength(fOffer[iO].Loc_House.GetEntrance, fDemand[iD].Loc_Unit.GetPosition);

   //For weapons production in cases with little resources available, they should be distributed
   //evenly between places rather than caring about route length.
   //This means weapon and armour smiths should get same amount of iron, even if one is closer to the smelter.
   if (fDemand[iD].Loc_House<>nil) and fResource.HouseDat[fDemand[iD].Loc_House.HouseType].DoesOrders
   and (fOffer[iO].Count < 3) //Little resources to share around
   and (fDemand[iD].Loc_House.CheckResIn(fDemand[iD].Ware) < 2) then //Few resources already delivered
     Result := 10 + KaMRandom(20);

   //Also prefer deliveries near to the serf
   if aSerf <> nil then
     Result := Result + KMLength(aSerf.GetPosition,fOffer[iO].Loc_House.GetEntrance);

   //Add some random element so in the case of identical bids the same resource will not always be chosen (e.g. weapons storehouse->barracks should take random weapon types not sequentially)
   Result := Result + KaMRandom(5);

   //Modifications for bidding system
   if (fDemand[iD].Ware = wt_All) //Always prefer deliveries House>House instead of House>Store
   or ((fOffer[iO].Loc_House.HouseType = ht_Store) //Prefer taking wares from House rather than Store...
   and (fDemand[iD].Ware <> wt_Warfare)) then    //...except weapons Store>Barracks, that is also prefered
     Result := Result + 1000;

   if (fDemand[iD].Loc_House <> nil) //Prefer delivering to houses with fewer supply
   and (fDemand[iD].Ware <> wt_All)
   and (fDemand[iD].Ware <> wt_Warfare) then //Except Barracks and Store, where supply doesn't matter or matter less
     Result := Result + 20 * fDemand[iD].Loc_House.CheckResIn(fDemand[iD].Ware);

   //Delivering weapons from store to barracks, make it lowest priority when there are >50 of that weapon in the barracks.
   //In some missions the storehouse has vast amounts of weapons, and we don't want the serfs to spend the whole game moving these.
   //In KaM, if the barracks has >200 weapons the serfs will stop delivering from the storehouse. I think our solution is better.
   if (fDemand[iD].Loc_House <> nil)
   and (fDemand[iD].Loc_House.HouseType = ht_Barracks)
   and (fOffer[iO].Loc_House.HouseType = ht_Store)
   and (fDemand[iD].Loc_House.CheckResIn(fOffer[iO].Ware) > 50) then
     Result := Result + 10000;

   //When delivering food to warriors, add a random amount to bid to ensure that a variety of food is taken. Also prefer food which is more abundant.
   if (fDemand[iD].Loc_Unit <> nil)
   and (fDemand[iD].Ware = wt_Food) then
     Result := Result + KaMRandom(5+(100 div fOffer[iO].Count)); //The more resource there is, the smaller Random can be. >100 we no longer care, it's just random 5.
end;

TDemandImportance = (
     diNorm,  //Everything (lowest importance)
     diHigh4, //Materials to workers
     diHigh3, //Food to Inn
     diHigh2, //Food to soldiers
     diHigh1  //Gold to School (highest importance)
     );